dnl $Id: configure.in,v 1.8 1998/01/23 09:33:16 rth Exp $

AC_INIT(insmod/insmod.c)
AC_PREFIX_DEFAULT(/usr)

AC_ARG_ENABLE(combined-insmod,
[  --disable-combined-insmod   Create insmod and rmmod as seperate binaries.],
[if test "$enableval" = "yes"; then
  COMBINE_INSMOD_RMMOD=y
else
  COMBINE_INSMOD_RMMOD=n
fi],[COMBINE_INSMOD_RMMOD=y])
AC_SUBST(COMBINE_INSMOD_RMMOD)

AC_CANONICAL_SYSTEM
case "$target_cpu" in
  alpha*)  ARCH=alpha ;;
  i?86)    ARCH=i386  ;;
  powerpc) ARCH=ppc   ;;
  *)       ARCH=$target_cpu ;;
esac
AC_SUBST(ARCH)

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_LN_S

dnl AC_MSG_CHECKING(for 2.1.x kernel includes)
dnl AC_TRY_RUN([
dnl #include <linux/unistd.h>
dnl int main(void) {
dnl #ifdef __NR_query_module
dnl return 0;
dnl #else
dnl return 1;
dnl #endif
dnl }],[AC_MSG_RESULT(found)],[AC_MSG_ERROR(not found)],
dnl [AC_MSG_RESULT(crosscompiling - no check)])

if test "$ARCH" = "alpha"; then
  AC_MSG_CHECKING(for broken alpha assembler)
  cat > conftest.c <<EOF
[#]line __oline__ "configure"
static int x, y;
int main() { return y; }
EOF
  if AC_TRY_EVAL(ac_compile); then
    ac_broken_gas=no
    if objdump -r conftest.o | grep 'LITERAL.*y.*4$' > /dev/null; then
      AC_DEFINE(AXP_BROKEN_GAS)
      ac_broken_gas=yes
    fi
    rm -rf conftest*
  else
    AC_MSG_ERROR(what, we can't build a simple proggie?)
  fi
  AC_MSG_RESULT($ac_broken_gas)
fi

# If the user did not specify a prefix, then change exec_prefix
# to be '' so that binaries go into /sbin.
if test "x$prefix" = "xNONE"; then
  if test "x$exec_prefix" = "xNONE"; then
    exec_prefix=""
  fi
fi

AC_OUTPUT(Makeconfig)